Condições Múltiplas

• Para testarmos e depurarmos condições múltiplas - precisamos construir um teste condicional composto - agregando condições individuais usando operador lógico and.

• IMPORTANTE: É sempre recomendado testar as condições individuais antes de agrupá-las em combinações maiores - assim você terá certeza que a combinação desejada é possível.

//@version=4
study("Condições Múltiplas")
i_period    = input(20)
i_bullLevel = input(55)
 
r = rsi(close, i_period)
 
// Condição #1.
rsiBull = r > i_bullLevel
// Condição #2.
hiChannel = highest(r, i_period * 2)[1]
aboveHiChannel = r > hiChannel
// Condição #3.
channelIsOld = hiChannel >= hiChannel[i_period]
// Condição #4.
historyIsBull = sum(rsiBull ? 1 : -1, i_period * 3) > 0
// Condições Múltiplas.
bull = rsiBull and aboveHiChannel and channelIsOld and historyIsBull
 
hline(i_bullLevel)
plot(r, "RSI", color.black)
plot(hiChannel, "High Channel")
 
plotchar(rsiBull ? i_bullLevel : na, "rIsBull", "1", location.absolute, color.green, size = size.tiny)
plotchar(aboveHiChannel ? r : na, "aboveHiChannel", "2", location.absolute, size = size.tiny)
plotchar(channelIsOld, "channelIsOld", "3", location.bottom, size = size.tiny)
plotchar(historyIsBull, "historyIsBull", "4", location.top, size = size.tiny)
bgcolor(bull ? not bull[1] ? color.new(color.green, 50) : color.green : na)

• Usamos plotchar() para mostrar o número de cada condição - evitando com que se sobreponham.

• As primeiras 2 plotchar() usam posições absolutas para mostrar o número da condição para que nos ajude a lembrar a condição correspondente.
  • A primeira, mostra “1” quando o RSI é maior que o valor definido pelo usuário - posiciona o valor “1” no “bull level”.

• Dois tons de verde são usados para colorir o fundo:
  • O mais claro identifica barras subsequentes onde nossas condições compostas são verdadeiras.

• IMPORTANTE: Apesar de ser possível armazenar o resultado de um teste condicional composto em uma variável bool única - pode ser argumentado que é mais de ler um código complexo quando as condições únicas tem variáveis independentes com nomes que nos ajudam a lembrar seu significado e então são combinadas com outras.