Candles Customizados

• Você pode criar barras e candles customizados em Pine usando as anotação plotbar e plotcandle.

//@version=4
study("Exemplo 1")
plotbar(open, high, low, close)

• Exemplo 1 simplesmente replica as barras do ativo atual.

//@version=4
study("Exemplo 2")
paleta = close >= open ? color.lime : color.red
plotbar(open, high, low, close, color=paleta)

• Exemplo 2 colore as barras baseando-se em uma condição

//@version=4
study("Exemplo 3")
c = close > open ? na : close
plotcandle(open, high, low, close, c)

• plotcandle é similar a plotbar - porém plota candles e possui um argumento opcional wickcolor como visto no exemplo 3.

• É possível plotar candles e barras usando outros valores ao invés dos valores OHLC, por exemplo, você pode calcular e plotar candles suavizados utilizando o seguinte código:

//@version=4
study("Exemplo 4")
len = input(9)
smooth(x) =>
    sma(x, len)
o = smooth(open)
h = smooth(high)
l = smooth(low)
c = smooth(close)
plotcandle(o, h, l, c)

• É possível também plotar valores OHLC de uma outra resolução, exemplo, plotar barras diárias no gráfico de 60 minutos.

// NOTA: adicionar esse código em um gráfico intraday
//@version=4
study("Exemplo 5")
higherRes = input("D", type=input.resolution)
is_newbar(res) =>
    t = time(res)
    not na(t) and (na(t[1]) or t > t[1])
o = security(syminfo.tickerid, higherRes, open)
h = security(syminfo.tickerid, higherRes, high)
l = security(syminfo.tickerid, higherRes, low)
c = security(syminfo.tickerid, higherRes, close)
plotbar(is_newbar(higherRes) ? o : na, h, l, c, color=c >= o ? color.lime : color.red)

• As anotações plotbar e plotcandle possuem um argumento title para que seja possível diferenciá-los na aba “Estilo” na caixa de “Configurações”.